テキストファイル変換ツール

Home > 便利ツール > テキストファイル変換ツール

Windows用のテキスト変換ツールです。
１）「参照ファイル」より、特定のパターンで記載された個所を抜きだし、一覧を作成します。
２）「処理ファイル」の中身から、特定のパターンにマッチした文字を探しだし、変換します。
３）「出力ファイル」に、変換後の結果を格納します。
下記スクリプトをreplace.vbs等の名前で保存し、「参照ファイル」「処理ファイル」と同じディレクトリに保存してからダブルクリック、または、コマンドプロンプトよりvbsファイルを指定して、実行してください。
★部分を書き換えることで、さまざまな変換に応用できます。
　　　→サンプル：参照ファイルに書かれた番号が含まれる行を消す

ソースファイル：

Option Explicit

'*************************
'１）「参照ファイル」より、特定のパターンで記載された個所を抜きだし、一覧を作成します。
'２）「処理ファイル」の中身から、特定のパターンにマッチした文字を探しだし、変換します。
'３）「出力ファイル」に、変換後の結果を格納します。
'このスクリプトをreplace.vbs等の名前で保存し、「参照ファイル」「処理ファイル」と同じ
'ディレクトリに保存してから、コマンドプロンプトより実行してください。
'*************************

Dim objFSO
Dim objSrcFile
Dim objWorkFile
Dim objResultFile
Dim objRegExp
Dim objMatches
Dim objSub

Dim lines()   '一覧格納用配列
Dim maxlines  '一覧配列数-1
Dim count     '変換された行数
count = 0
Dim i         'ループ用

Dim srcFileName
Dim workFileName
Dim resultFileName
Dim strPattern
Dim strPre
Dim strPost
Dim strAfter
Dim strScriptPath
Dim strText

'---★ここに、参照ファイル、処理ファイル、変換結果の出力ファイル名を記載してください。
srcFileName = "match.txt"      '参照ファイル
workFileName ="input.txt"     '処理ファイル
resultFileName = "output.txt"  '出力ファイル

'---★パターン抽出用文字列を記載してください。
'---（正規表現利用。()で囲まれた部分が一覧として取り出されます。）
strPattern = "右の番号を含む行を削除します。：([\d]+)"

'---★変更後の文字列を記載してください。
'---strPre＋一覧上の文字列＋strPost　の個所を、strAfterに変換します。
strPre = ".*"
strPost = ".*\n"
strAfter = vbNullString

'******事前処理******

'スクリプトの実行パスを取得する。
strScriptPath = Replace(WScript.ScriptFullName,WScript.ScriptName,"")

'ファイルハンドリング用のオブジェクトを作成する。
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
If Err.Number <> 0 Then
  WScript.Echo "ファイルオブジェクト作成エラー: " & Err.Description
End If

'******削除用の番号一覧を作成******

'参照ファイルをオープンする。
Set objSrcFile = objFSO.OpenTextFile(strScriptPath+srcFileName,1)
If Err.Number <> 0 Then
  WScript.Echo "参照ファイルオープンエラー: " & Err.Description
End If

'正規表現用のオブジェクトを作成する。
Set objRegExp = CreateObject("VBScript.RegExp")

objRegExp.Pattern = strPattern
objRegExp.Global = True

'参照ファイルを読み込む。
strText = objSrcFile.ReadAll

'削除用の番号一覧を抽出する。
Set objMatches = objRegExp.Execute(strText)
maxlines = objMatches.Count - 1
If maxlines >= 0 Then
  ReDim lines(maxlines)
  For i=0 To maxlines
    Set objSub = objMatches.Item(i).SubMatches
    lines(i) = objSub.Item(0)
  Next
End If

'参照ファイルをクローズする。
objSrcFile.Close

'ファイルオブジェクトをクリアする。
Set objSrcFile = Nothing

'******処理ファイルを読み込み、削除処理を実行******

'処理ファイルをオープンする。
Set objWorkFile = objFSO.OpenTextFile(strScriptPath+workFileName,1)
If Err.Number <> 0 Then
  WScript.Echo "処理ファイルオープンエラー: " & Err.Description
End If

'処理ファイルをメモリに読み込む。
strText = objWorkFile.ReadAll

'番号に該当する個所を変換する。
For i=0 To maxlines
  objRegExp.Pattern = strPre+lines(i)+strPost
  set objMatches = objRegExp.Execute(strText)
  strText = objRegExp.Replace(strText, strAfter)
  count = count + objMatches.Count
Next

'処理ファイルをクローズする。
objWorkFile.Close

'ファイルオブジェクトをクリアする。
Set objWorkFile = Nothing

'******結果を出力ファイルに書き込み******

'出力ファイルをオープンする。
Set objResultFile = objFSO.OpenTextFile(strScriptPath+resultFileName,2,True)
If Err.Number <> 0 Then
  WScript.Echo "出力ファイルオープンエラー: " & Err.Description
End If

objResultFile.Write(strText)

'出力ファイルをクローズする。
objResultFile.Close

'ファイルオブジェクトをクリアする。
Set objResultFile = Nothing

'******結果出力＆後処理******
WScript.Echo "変換対象リストは" & (maxlines+1) & "個です。"
WScript.Echo "変換された個所は" & count & "個所です。"
Set objFSO = Nothing